Een trade per dag

[Bakstenen]

Eric ik maak even een nieuw onderwerp aan.
Ik heb de indicator http://www.ta-script.com/forum/viewtopi ... n&start=15
Je weet het, ik begin met de letter a en eindig bij z.
Maar ik wil deze nu ook intraday testten, ik heb de instellingen staan zoals hieronder, alleen krijg ik rare uitvoeringen, ik zie b.v in de grafiek niet een signaal om 17.30
Wil jij een voorbeeld geven hoe ik de instellingen moet invoeren.

[Eric]

Deze indicator werkt uitsluitend in een intraday grafiek, niet in een daggrafiek.

Ik zie wel signalen, maar deze indicator is gemaakt om de ene dag na een opgegeven tijd een trade te openen en de volgende dag na een opgegeven tijd de trade te sluiten. Dat maakt hem in zoverre warrig dat het moment waarop hij begint met traden een dag kan verspringen als je gaat uitzoomen, omdat er dan meer data wordt meegenomen. Is dat wellicht het probleem?

---
Eric

[Bakstenen]

Oke, kan jij dan een indicator maken die ook intraday werkt

[Eric]

Bedoel je dat hij dezelfde dag moet sluiten na de op te geven tijd, en niet de volgende dag?

—-
Eric

[Bakstenen]

Klopt, wel zelf tijd ingeven

[Eric]

Dat wordt zoiets:

Code: Selecteer alles

{- Filename: Bakstenen close-open systeem 2 -}

var
  i, LongDay: integer;
  dOpen, DofW: integer;
  tOpen, tClose, BarTime: TDateTime;
  Long: boolean;
begin
  dOpen := 1 + CreateParameterSelect('Open koop dag', 'Elke'#9'Maandag'#9'Dinsdag'#9'Woensdag'#9'Donderdag'#9'Vrijdag', 0, true);
  tOpen := CreateParameterTime('Open koop moment', 17.75/24);
  tClose := CreateParameterTime('Sluit verkoop moment', 8.00/24);

{ Indicator eigenschappen }
  with Indicator do 
  begin
    NewBand := false;
    ScaleRange := srAuto;       // indicatorschaal automatisch
    SignalView := svShowInMain;
    AdvancedTrades := true;
  end;

{ Berekening }
  for i:=0 to BarCount-1 do
  begin
    BarTime := frac(DateTime[i]);
    DofW := DayOfWeek(DateTime[i]);
    if Long and (BarTime >= tClose) then
    begin
      ExitLongAtOpen(i);
      Long := false;
    end else
    if not Long and (BarTime >= tOpen) and (trunc(DateTime[i]) <> LongDay) and ((dOpen = 1) or (dOpen = dofW)) then
    begin
      EnterLongAtOpen(i);
      Long := true;
      LongDay := trunc(DateTime[i]);
    end;
  end;
end.

---
Eric

[Bakstenen]

Bedankt, het werkt

[Bakstenen]

Vraag niet hoe, maar ik krijg het voor elkaar.
Eric waarom sluit de indicator bij de cac future de trade in de volgende candle?

[Eric]

Omdat je hebt ingesteld dat je de positie wilt sluiten na 8:59. Deze indicator sluit dezelfde dag, het is de volgende candle na entry later dan 8:59, dus wordt-ie gesloten.

—-
Eric

[Bakstenen]

Eric, wat kan het leven toch simpel zijn, mits je oplet.

[Bakstenen]

Eric,
ben blij met de indicator, is het mogelijk om een trailing stop in te bouwen? en dan voor de trading simulatie

[Eric]

Dat kan. Ik zal even aangeven hoe de trades nu worden gedaan:
- de opening gebeurt op de eerste bar met een tijd >= de opgegeven tijd, tegen de openingskoers
- de normale sluiting gebeurt op de eerste bar met een tijd >= de opgegeven tijd, tegen de openingskoers
- de trailing stop wordt initieel berekend op de openingskoers en daarna met hoogste koersen per bar
- de stop wordt uitgevoerd als de low van de bar onder de stop komt

Code: Selecteer alles

{- Filename: Bakstenen close-open systeem 3 -}

var
  i, LongDay: integer;
  dOpen, DofW: integer;
  tOpen, tClose, BarTime: TDateTime;
  Long: boolean;
  nStopPct, Stop: real;
  sStop: TSeries;
begin
  dOpen := 1 + CreateParameterSelect('Open koop dag', 'Elke'#9'Maandag'#9'Dinsdag'#9'Woensdag'#9'Donderdag'#9'Vrijdag', 0, true);
  tOpen := CreateParameterTime('Open koop moment', 17.5/24);
  tClose := CreateParameterTime('Sluit verkoop moment', 22.00/24);
  nStopPct := CreateParameterReal('Trailing stop %', 0, 99, 0, true);

{ Indicator eigenschappen }
  with Indicator do 
  begin
    NewBand := false;
    ScaleRange := srCommon;
    SignalView := svShowInMain;
    AdvancedTrades := true;
  end;

{ Berekening }
  sStop := CreateSeries(BarCount);
  for i:=0 to BarCount-1 do
  begin
    BarTime := frac(DateTime[i]);
    DofW := DayOfWeek(DateTime[i]);
    if Long then
    begin
      if BarTime >= tClose then
      begin
        ExitLongAtOpen(i);
        Long := false;
      end else
      if (nStopPct <> 0) and (Low[i] <= Stop) then
      begin
        if ExitLongStop(i, Stop) then Long := false;
      end;
      Stop := Max(Stop, High[i] * (100-nStopPct)/100.0);
      if nStopPct <> 0 then sStop[i] := Stop;
    end else
    if not Long and (BarTime >= tOpen) and (trunc(DateTime[i]) <> LongDay) and ((dOpen = 1) or (dOpen = dofW)) then
    begin
      EnterLongAtOpen(i);
      Long := true;
      LongDay := trunc(DateTime[i]);
      Stop := Open[i] * (100-nStopPct)/100.0;
      if nStopPct <> 0 then sStop[i] := Stop;
    end;
  end;
  
  with CreateLine(sStop) do
  begin
    Color := clSilver;
    LineType := ltDot;
  end;
end.

---
Eric

[Bakstenen]

Bedankt ik ga er mee aan de slag,
maar ik wil de indicator met Filename: Bakstenen close-open systeem 2 -behouden, kan jij deze een andere naam geven zodat de andere bewaard bijft

[Eric]

Ik heb het aangepast, maar je kunt zelf ook altijd de naam van de indicator opgeven wanneer je hem installeert.

---
Eric

[Bakstenen]

Weet ik, maar dan geeft het geen verwarring, praten we altijd over hetzelfde